VLOOKUP Function sa Excel – Gabay sa Baguhan: Syntax at Mga Halimbawa

Nilalaman

VLOOKUP function sa Excel – pangkalahatang paglalarawan at syntax
- Syntax ng VLOOKUP function
Mga Halimbawa ng VLOOKUP
Eksaktong o tinatayang tugma sa VLOOKUP function
- Halimbawa 1: Paghahanap ng Eksaktong Tugma sa VLOOKUP
- Halimbawa 2: Paggamit ng VLOOKUP para Maghanap ng Tinatayang Tugma
VLOOKUP sa Excel – kailangan mong tandaan ito!

Ngayon ay nagsisimula kami ng isang serye ng mga artikulo na naglalarawan sa isa sa mga pinakakapaki-pakinabang na tampok ng Excel − VPR (VLOOKUP). Ang function na ito, sa parehong oras, ay isa sa mga pinaka kumplikado at hindi gaanong naiintindihan.

Sa tutorial na ito sa VPR Susubukan kong ilatag ang mga pangunahing kaalaman hangga't maaari upang gawing malinaw ang proseso ng pag-aaral hangga't maaari para sa mga walang karanasan na gumagamit. Bilang karagdagan, pag-aaralan namin ang ilang mga halimbawa na may mga formula ng Excel na magpapakita ng pinakakaraniwang mga kaso ng paggamit para sa function VPR.

VLOOKUP function sa Excel – pangkalahatang paglalarawan at syntax

Kaya ano ito VPR? Well, una sa lahat, ito ay isang Excel function. Anong ginagawa niya? Hinahanap nito ang halagang iyong tinukoy at ibinabalik ang katumbas na halaga mula sa kabilang column. Sa teknikal na pagsasalita, VPR hinahanap ang value sa unang column ng ibinigay na range at ibinabalik ang resulta mula sa isa pang column sa parehong row.

Sa pinakakaraniwang application, ang function VPR naghahanap sa database para sa isang naibigay na natatanging identifier at kinukuha ang ilang impormasyong nauugnay dito mula sa database.

Unang titik sa pangalan ng function VPR (VLOOKUP) ibig sabihin Вpatayo (Vpatayo). Sa pamamagitan nito maaari mong makilala VPR mula GPR (HLOOKUP), na naghahanap ng value sa tuktok na row ng isang range − Гpahalang (Hpahalang).

tungkulin VPR available sa Excel 2013, Excel 2010, Excel 2007, Excel 2003, Excel XP, at Excel 2000.

Syntax ng VLOOKUP function

tungkulin VPR (VLOOKUP) ay may sumusunod na syntax:

VLOOKUP(lookup_value,table_array,col_index_num,[range_lookup])

ВПР(искомое_значение;таблица;номер_столбца;[интервальный_просмотр])

Tulad ng nakikita mo, isang function VPR sa Microsoft Excel ay may 4 na opsyon (o mga argumento). Ang unang tatlo ay sapilitan, ang huli ay opsyonal.

lookup_value (lookup_value) – Ang halagang hahanapin. Ito ay maaaring isang value (numero, petsa, text) o isang cell reference (naglalaman ng lookup value), o isang value na ibinalik ng ilang ibang Excel function. Halimbawa, hahanapin ng formula na ito ang halaga 40:
=VLOOKUP(40,A2:B15,2)
=ВПР(40;A2:B15;2)

Kung ang halaga ng paghahanap ay mas mababa kaysa sa pinakamaliit na halaga sa unang hanay ng hanay na hinahanap, ang function VPR mag-uulat ng error #AT (#N/A).

table_array (talahanayan) – dalawa o higit pang column ng data. Tandaan, ang function VPR laging hinahanap ang value sa unang column ng range na ibinigay sa argument table_array (talahanayan). Ang natitingnang hanay ay maaaring maglaman ng iba't ibang data, gaya ng text, petsa, numero, boolean. Ang function ay case insensitive, ibig sabihin, ang mga upper at lower case na character ay itinuturing na pareho. Kaya hahanapin ng aming formula ang halaga 40 sa mga cell mula sa A2 sa A15, dahil ang A ay ang unang column ng hanay na A2:B15 na ibinigay sa argumento table_array (talahanayan):
=VLOOKUP(40,A2:B15,2)
=ВПР(40;A2:B15;2)

col_index_num (column_number) ay ang numero ng column sa ibinigay na hanay kung saan ibabalik ang halaga sa nahanap na row. Ang pinakakaliwang column sa ibinigay na hanay ay 1, ang pangalawang hanay ay 2, ang ikatlong hanay ay 3 at iba pa. Ngayon ay maaari mong basahin ang buong formula:
=VLOOKUP(40,A2:B15,2)
=ВПР(40;A2:B15;2)
Formula na naghahanap ng halaga 40 sa hanay A2: A15 at ibinabalik ang katumbas na halaga mula sa column B (dahil ang B ay ang pangalawang column sa hanay na A2:B15).

Kung ang halaga ng argumento col_index_num (column_number) mas mababa sa 1pagkatapos VPR mag-uulat ng error #VALUE! (#VALUE!). At kung ito ay higit pa sa bilang ng mga column sa hanay table_array (talahanayan), ang function ay magbabalik ng isang error #REF! (#LINK!).

range_lookup (range_lookup) – tinutukoy kung ano ang hahanapin:
- eksaktong tugma, dapat na pantay ang argumento FALSE (MALI);
- tinatayang tugma, katumbas ng argumento TUNAY NA CODE (TRUE) o hindi tinukoy sa lahat.
Ang parameter na ito ay opsyonal, ngunit napakahalaga. Mamaya sa tutorial na ito sa VPR Ipapakita ko sa iyo ang ilang mga halimbawa na nagpapaliwanag kung paano magsulat ng mga formula para sa paghahanap ng eksakto at tinatayang mga tugma.

Mga Halimbawa ng VLOOKUP

Sana ang function VPR maging mas malinaw sa iyo ng kaunti. Ngayon tingnan natin ang ilang mga kaso ng paggamit VPR sa mga formula na may totoong data.

Paano gamitin ang VLOOKUP para maghanap sa isa pang Excel sheet

Sa pagsasagawa, mga formula na may function VPR ay bihirang ginagamit upang maghanap ng data sa parehong worksheet. Mas madalas kaysa sa hindi, hahanapin mo at kukunin ang mga katumbas na halaga mula sa isa pang sheet.

Upang magamit VPR, maghanap sa isa pang Microsoft Excel sheet, Dapat mong nasa argumento table_array (talahanayan) tukuyin ang pangalan ng sheet na may tandang padamdam na sinusundan ng hanay ng mga cell. Halimbawa, ang sumusunod na formula ay nagpapakita na ang hanay A2: B15 ay nasa isang sheet na pinangalanan Sheet2.

=VLOOKUP(40,Sheet2!A2:B15,2)

=ВПР(40;Sheet2!A2:B15;2)

Siyempre, hindi kailangang manu-manong ipasok ang pangalan ng sheet. Simulan lang ang pag-type ng formula, at pagdating sa argumento table_array (talahanayan), lumipat sa nais na sheet at piliin ang nais na hanay ng mga cell gamit ang mouse.

Hinahanap ng formula na ipinapakita sa screenshot sa ibaba ang text na "Produkto 1" sa column A (ito ang unang column ng range A1:B2) sa isang worksheet Presyo.

=VLOOKUP("Product 1",Prices!$A$2:$B$9,2,FALSE)

=ВПР("Product 1";Prices!$A$2:$B$9;2;ЛОЖЬ)

Mangyaring tandaan na kapag naghahanap ng isang halaga ng teksto, dapat mong ilakip ito sa mga panipi (“”), gaya ng karaniwang ginagawa sa mga formula ng Excel.

Para sa argumento table_array (talahanayan) ito ay kanais-nais na palaging gumamit ng ganap na mga sanggunian (na may $ sign). Sa kasong ito, ang hanay ng paghahanap ay mananatiling hindi nagbabago kapag kinokopya ang formula sa ibang mga cell.

Maghanap sa isa pang workbook gamit ang VLOOKUP

Upang gumana VPR nagtrabaho sa pagitan ng dalawang Excel workbook, kailangan mong tukuyin ang pangalan ng workbook sa mga square bracket bago ang pangalan ng sheet.

Halimbawa, sa ibaba ay isang formula na naghahanap ng halaga 40 sa sheet Sheet2 sa aklat Numbers.xlsx:

=VLOOKUP(40,[Numbers.xlsx]Sheet2!A2:B15,2)

=ВПР(40;[Numbers.xlsx]Sheet2!A2:B15;2)

Narito ang pinakamadaling paraan upang lumikha ng isang formula sa Excel gamit ang VPRna nagli-link sa isa pang workbook:

Buksan ang dalawang libro. Hindi ito kinakailangan, ngunit mas madaling gumawa ng formula sa ganitong paraan. Hindi mo gustong ipasok ang pangalan ng workbook nang manu-mano, hindi ba? Bilang karagdagan, mapoprotektahan ka nito mula sa mga hindi sinasadyang typo.
Magsimulang mag-type ng function VPRat pagdating sa argumento table_array (talahanayan), lumipat sa ibang workbook at piliin ang kinakailangang hanay ng paghahanap dito.

Ang screenshot sa ibaba ay nagpapakita ng formula na ang paghahanap ay nakatakda sa isang hanay sa workbook PriceList.xlsx sa sheet Presyo.

tungkulin VPR gagana kahit na isara mo ang hinanap na workbook at ang buong path sa workbook file ay lalabas sa formula bar, tulad ng ipinapakita sa ibaba:

Kung ang pangalan ng workbook o sheet ay naglalaman ng mga puwang, dapat itong nakapaloob sa mga kudlit:

=VLOOKUP(40,'[Numbers.xlsx]Sheet2'!A2:B15,2)

=ВПР(40;'[Numbers.xlsx]Sheet2'!A2:B15;2)

Paano gumamit ng pinangalanang hanay o talahanayan sa mga formula na may VLOOKUP

Kung plano mong gamitin ang parehong hanay ng paghahanap sa maraming function VPR, maaari kang lumikha ng pinangalanang hanay at ilagay ang pangalan nito sa formula bilang argumento table_array (talahanayan).

Upang lumikha ng pinangalanang hanay, piliin lamang ang mga cell at maglagay ng naaangkop na pangalan sa field Pangalan, sa kaliwa ng formula bar.

Ngayon ay maaari mong isulat ang sumusunod na formula para sa paghahanap ng presyo ng isang produkto Produkto 1:

=VLOOKUP("Product 1",Products,2)

=ВПР("Product 1";Products;2)

Karamihan sa mga pangalan ng hanay ay gumagana para sa buong workbook ng Excel, kaya hindi na kailangang tukuyin ang pangalan ng sheet para sa argumento table_array (talahanayan), kahit na ang formula at ang hanay ng paghahanap ay nasa magkaibang worksheet. Kung nasa iba't ibang workbook ang mga ito, bago ang pangalan ng hanay kailangan mong tukuyin ang pangalan ng workbook, halimbawa, tulad nito:

=VLOOKUP("Product 1",PriceList.xlsx!Products,2)

=ВПР("Product 1";PriceList.xlsx!Products;2)

Kaya mukhang mas malinaw ang formula, sang-ayon? Gayundin, ang paggamit ng mga pinangalanang hanay ay isang magandang alternatibo sa mga ganap na sanggunian dahil ang pinangalanang hanay ay hindi nagbabago kapag kinopya mo ang formula sa ibang mga cell. Nangangahulugan ito na maaari mong tiyakin na ang hanay ng paghahanap sa formula ay palaging mananatiling tama.

Kung iko-convert mo ang isang hanay ng mga cell sa isang ganap na spreadsheet ng Excel gamit ang command mesa (Talahanayan) tab pagpapasok (Ipasok), pagkatapos kapag pumili ka ng isang hanay gamit ang mouse, awtomatikong idaragdag ng Microsoft Excel ang mga pangalan ng column (o ang pangalan ng talahanayan kung pipiliin mo ang buong talahanayan) sa formula.

Ang natapos na formula ay magiging ganito:

=VLOOKUP("Product 1",Table46[[Product]:[Price]],2)

=ВПР("Product 1";Table46[[Product]:[Price]];2)

O baka naman ganito:

=VLOOKUP("Product 1",Table46,2)

=ВПР("Product 1";Table46;2)

Kapag gumagamit ng mga pinangalanang hanay, ang mga link ay ituturo sa parehong mga cell kahit saan mo kopyahin ang function VPR sa loob ng workbook.

Paggamit ng Mga Wildcard sa Mga Formula ng VLOOKUP

Tulad ng maraming iba pang mga pag-andar, VPR Maaari mong gamitin ang mga sumusunod na wildcard na character:

Tandang pananong (?) – pumapalit sa alinmang karakter.
Asterisk (*) – pinapalitan ang anumang pagkakasunod-sunod ng mga character.

Paggamit ng Mga Wildcard sa Mga Function VPR maaaring maging kapaki-pakinabang sa maraming kaso, halimbawa:

Kapag hindi mo eksaktong matandaan ang teksto na kailangan mong hanapin.
Kapag gusto mong makahanap ng ilang salita na bahagi ng nilalaman ng isang cell. Alam mo yan VPR naghahanap ayon sa mga nilalaman ng cell sa kabuuan, na parang pinagana ang opsyon Itugma ang buong nilalaman ng cell (Buong cell) sa karaniwang paghahanap sa Excel.
Kapag ang isang cell ay naglalaman ng mga karagdagang espasyo sa simula o dulo ng nilalaman. Sa ganoong sitwasyon, maaari mong i-rack ang iyong mga utak sa loob ng mahabang panahon, sinusubukan mong malaman kung bakit hindi gumagana ang formula.

Halimbawa 1: Naghahanap ng text na nagsisimula o nagtatapos sa ilang partikular na character

Sabihin nating gusto mong maghanap ng partikular na customer sa database na ipinapakita sa ibaba. Hindi mo matandaan ang kanyang apelyido, ngunit alam mo na nagsisimula ito sa "ack". Narito ang isang pormula na gagawin ng maayos ang trabaho:

=VLOOKUP("ack*",$A$2:$C$11,1,FALSE)

=ВПР("ack*";$A$2:$C$11;1;ЛОЖЬ)

Ngayong sigurado ka na na natagpuan mo na ang tamang pangalan, maaari mong gamitin ang parehong formula upang mahanap ang halagang binayaran ng customer na ito. Upang gawin ito, baguhin lamang ang ikatlong argumento ng function VPR sa nais na numero ng hanay. Sa aming kaso, ito ang column C (ika-3 sa hanay):

=VLOOKUP("ack*",$A$2:$C$11,3,FALSE)

=ВПР("ack*";$A$2:$C$11;3;ЛОЖЬ)

Narito ang ilan pang halimbawa na may mga wildcard:

~ Maghanap ng pangalan na nagtatapos sa "lalaki":

=VLOOKUP("*man",$A$2:$C$11,1,FALSE)

=ВПР("*man";$A$2:$C$11;1;ЛОЖЬ)

~ Maghanap ng pangalan na nagsisimula sa "ad" at nagtatapos sa "anak":

=VLOOKUP("ad*son",$A$2:$C$11,1,FALSE)

=ВПР("ad*son";$A$2:$C$11;1;ЛОЖЬ)

~ Nakita namin ang unang pangalan sa listahan, na binubuo ng 5 character:

=VLOOKUP("?????",$A$2:$C$11,1,FALSE)

=ВПР("?????";$A$2:$C$11;1;ЛОЖЬ)

Upang gumana VPR na may mga wildcard ay gumana nang tama, bilang ang ikaapat na argumento ay dapat mong palaging gamitin FALSE (MALI). Kung ang hanay ng paghahanap ay naglalaman ng higit sa isang halaga na tumutugma sa mga termino para sa paghahanap sa mga wildcard, ibabalik ang unang halaga na natagpuan.

Halimbawa 2: Pagsamahin ang mga wildcard at cell reference sa mga formula ng VLOOKUP

Ngayon tingnan natin ang isang bahagyang mas kumplikadong halimbawa kung paano maghanap gamit ang function VPR ayon sa halaga sa isang cell. Isipin na ang column A ay isang listahan ng mga license key, at ang column B ay isang listahan ng mga pangalan na nagmamay-ari ng lisensya. Bilang karagdagan, mayroon kang bahagi (ilang character) ng ilang uri ng key ng lisensya sa cell C1, at gusto mong hanapin ang pangalan ng may-ari.

Magagawa ito gamit ang sumusunod na formula:

=VLOOKUP("*"&C1&"*",$A$2:$B$12,2,FALSE)

=ВПР("*"&C1&"*";$A$2:$B$12;2;FALSE)

Hinahanap ng formula na ito ang value mula sa cell C1 sa ibinigay na hanay at ibinabalik ang katumbas na halaga mula sa column B. Tandaan na sa unang argumento, gumagamit kami ng ampersand (&) na character bago at pagkatapos ng cell reference upang i-link ang string ng text.

Tulad ng makikita mo sa figure sa ibaba, ang function VPR ibinabalik ang "Jeremy Hill" dahil ang kanyang license key ay naglalaman ng pagkakasunod-sunod ng mga character mula sa cell C1.

Tandaan na ang argumento table_array (talahanayan) sa screenshot sa itaas ay naglalaman ng pangalan ng talahanayan (Talahanayan7) sa halip na tumukoy ng hanay ng mga cell. Ito ang ginawa natin sa nakaraang halimbawa.

Eksaktong o tinatayang tugma sa VLOOKUP function

At sa wakas, tingnan natin ang huling argumento na tinukoy para sa function VPR - range_lookup (interval_view). Gaya ng nabanggit sa simula ng aralin, ang argumentong ito ay napakahalaga. Maaari kang makakuha ng ganap na magkakaibang mga resulta sa parehong formula na may halaga nito TUNAY NA CODE (TAMA) o FALSE (MALI).

Una, alamin natin kung ano ang ibig sabihin ng Microsoft Excel ng eksakto at tinatayang mga tugma.

Kung ang argumento range_lookup (range_lookup) ay katumbas ng FALSE (FALSE), ang formula ay naghahanap ng eksaktong tugma, ibig sabihin, eksaktong kaparehong halaga tulad ng ibinigay sa argumento lookup_value (lookup_value). Kung sa unang hanay ng hanay table_array (talahanayan) ay nakatagpo ng dalawa o higit pang mga halaga na tumutugma sa argumento lookup_value (search_value), pagkatapos ay pipiliin ang una. Kung walang nakitang mga tugma, mag-uulat ang function ng error #AT (#N/A). Halimbawa, mag-uulat ng error ang sumusunod na formula #AT (#N/A) kung walang value sa range A2:A15 4:
=VLOOKUP(4,A2:B15,2,FALSE)
=ВПР(4;A2:B15;2;ЛОЖЬ)
Kung ang argumento range_lookup (range_lookup) ay katumbas ng TUNAY NA CODE (TRUE), naghahanap ang formula ng tinatayang tugma. Mas tiyak, una ang function VPR naghahanap ng eksaktong tugma, at kung walang mahanap, pipili ng tinatayang isa. Ang tinatayang tugma ay ang pinakamalaking halaga na hindi lalampas sa halagang tinukoy sa argumento. lookup_value (lookup_value).

Kung ang argumento range_lookup (range_lookup) ay katumbas ng TUNAY NA CODE (TRUE) o hindi tinukoy, kung gayon ang mga halaga sa unang hanay ng hanay ay dapat na pagbukud-bukurin sa pataas na pagkakasunud-sunod, iyon ay, mula sa pinakamaliit hanggang sa pinakamalaki. Kung hindi, ang pag-andar VPR maaaring magbalik ng maling resulta.

Upang mas maunawaan ang kahalagahan ng pagpili TUNAY NA CODE (KATOTOHANAN) o FALSE (FALSE), tingnan natin ang ilan pang mga formula na may function VPR at tingnan ang mga resulta.

Halimbawa 1: Paghahanap ng Eksaktong Tugma sa VLOOKUP

Tulad ng naaalala mo, upang maghanap ng eksaktong tugma, ang ikaapat na argumento ng function VPR dapat mahalaga FALSE (MALI).

Bumalik tayo sa talahanayan mula sa pinakaunang halimbawa at alamin kung aling hayop ang maaaring gumalaw nang mabilis 50 milya kada oras. Naniniwala ako na ang formula na ito ay hindi magdudulot sa iyo ng anumang mga paghihirap:

=VLOOKUP(50,$A$2:$B$15,2,FALSE)

=ВПР(50;$A$2:$B$15;2;ЛОЖЬ)

Tandaan na ang aming hanay ng paghahanap (column A) ay naglalaman ng dalawang value 50 - sa mga cell A5 и A6. Ang formula ay nagbabalik ng halaga mula sa cell B5. Bakit? Dahil kapag naghahanap ng eksaktong tugma, ang function VPR ginagamit ang unang halaga na natagpuan na tumutugma sa hinahanap.

Halimbawa 2: Paggamit ng VLOOKUP para Maghanap ng Tinatayang Tugma

Kapag ginamit mo ang function VPR upang maghanap ng tinatayang tugma, ibig sabihin, kapag ang argumento range_lookup (range_lookup) ay katumbas ng TUNAY NA CODE (TRUE) o tinanggal, ang unang bagay na kailangan mong gawin ay pagbukud-bukurin ang hanay ayon sa unang column sa pataas na pagkakasunud-sunod.

Ito ay napakahalaga dahil ang pag-andar VPR ibinabalik ang susunod na pinakamalaking halaga pagkatapos ng ibinigay na isa, at pagkatapos ay huminto ang paghahanap. Kung papabayaan mo ang tamang pag-uuri, magkakaroon ka ng mga kakaibang resulta o isang mensahe ng error. #AT (#N/A).

Ngayon ay maaari mong gamitin ang isa sa mga sumusunod na formula:

=VLOOKUP(69,$A$2:$B$15,2,TRUE) or =VLOOKUP(69,$A$2:$B$15,2)

=ВПР(69;$A$2:$B$15;2;ИСТИНА) or =ВПР(69;$A$2:$B$15;2)

Tulad ng nakikita mo, gusto kong malaman kung alin sa mga hayop ang may pinakamalapit na bilis 69 milya kada oras. At narito ang resulta na ibinalik sa akin ang function VPR:

Gaya ng nakikita mo, nagbalik ang formula ng resulta Antelope (Antelope), na ang bilis 61 milya kada oras, bagama't kasama rin sa listahan Cheetah (Cheetah) na tumakbo ng mabilis 70 milya kada oras, at ang 70 ay mas malapit sa 69 kaysa sa 61, hindi ba? Bakit ito nangyayari? Dahil ang function VPR kapag naghahanap ng tinatayang tugma, ibinabalik ang pinakamalaking halaga na hindi mas malaki kaysa sa hinahanap.

Umaasa ako na ang mga halimbawang ito ay nagbigay ng kaunting liwanag sa pagtatrabaho sa function VPR sa Excel, at hindi mo na siya tinitingnan bilang isang tagalabas. Ngayon ay hindi masakit na ulitin sa madaling sabi ang mga pangunahing punto ng materyal na aming pinag-aralan upang mas mahusay na ayusin ito sa memorya.

VLOOKUP sa Excel – kailangan mong tandaan ito!

tungkulin VPR Hindi makatingin sa kaliwa ang Excel. Palagi nitong hinahanap ang halaga sa pinakakaliwang column ng hanay na ibinigay ng argumento table_array (talahanayan).
Sa pagpapaandar VPR lahat ng value ay case-insensitive, ibig sabihin, ang maliliit at malalaking letra ay katumbas.
Kung ang halaga na iyong hinahanap ay mas mababa sa pinakamababang halaga sa unang hanay ng hanay na hinahanap, ang function VPR mag-uulat ng error #AT (#N/A).
Kung ika-3 argumento col_index_num (column_number) mas mababa sa 1tungkulin VPR mag-uulat ng error #VALUE! (#VALUE!). Kung mas malaki ito sa bilang ng mga column sa hanay table_array (talahanayan), ang function ay mag-uulat ng isang error #REF! (#LINK!).
Gumamit ng ganap na mga sanggunian ng cell sa argumento table_array (talahanayan) upang mapanatili ang tamang hanay ng paghahanap kapag kinokopya ang formula. Subukang gumamit ng mga pinangalanang hanay o talahanayan sa Excel bilang alternatibo.
Kapag gumagawa ng tinatayang paghahanap ng tugma, tandaan na ang unang column sa hanay na iyong hinahanap ay dapat na pagbukud-bukurin sa pataas na pagkakasunud-sunod.
Panghuli, alalahanin ang kahalagahan ng ikaapat na argumento. Gumamit ng mga halaga TUNAY NA CODE (KATOTOHANAN) o FALSE (MALI) kusa at mapupuksa mo ang maraming sakit ng ulo.

Sa mga sumusunod na artikulo ng aming function na tutorial VPR sa Excel, matututo tayo ng mas advanced na mga halimbawa, tulad ng pagsasagawa ng iba't ibang kalkulasyon gamit ang VPR, pagkuha ng mga halaga mula sa maraming column, at higit pa. Salamat sa pagbabasa ng tutorial na ito at inaasahan kong makita ka muli sa susunod na linggo!